I have created some new template user fields for "User Name" which are filled by calling this function:

Function Template_GetFullName(UserID)
  On Error Resume Next
         'Represents a single server connection to the ALM-Server
         Dim objtdc
         'Customization services Objekt
         Dim objcustomization
         'The collection of all CustomizationUser objects
         Dim objCustUsers
         'Represents a user
         Dim objUser

         'TD-Connection aufbauen
         set objtdc = TDConnection

         Set objcustomization = objtdc.Customization

         Set objCustUsers = objcustomization.Users

         Set objUser = objCustUsers.User(UserID)

         'Vollständigen Namen auslesen und zurückgeben
         Template_GetFullName = objUser.FullName

         Set objtdc = Nothing
         Set objcustomization = Nothing
         Set objCustUsers = Nothing
         Set objUser = Nothing

  On Error GoTo 0
End Function

This is call e.g. in Template_Bug_MoveTo, Template_Bug_New,Template_Bug_FieldChange(FieldName) , Test_MoveTo

    if Bug_Fields.Field("BG_DETECTED_BY").Value = "" then
       Bug_Fields.Field("BG_USER_TEMPLATE_03").Value = ""

    Elseif Bug_Fields.Field("BG_DETECTED_BY").Value <> "" and Bug_Fields.Field("BG_USER_TEMPLATE_03").Value ="" then
       Bug_Fields.Field("BG_USER_TEMPLATE_03").Value = Template_GetFullName(Bug_Fields.Field("BG_DETECTED_BY").Value)
    End if

    if Bug_Fields.Field("BG_RESPONSIBLE").Value = "" then
       Bug_Fields.Field("BG_USER_TEMPLATE_04").Value = ""

    Elseif Bug_Fields.Field("BG_RESPONSIBLE").Value <> "" and Bug_Fields.Field("BG_USER_TEMPLATE_04").Value = "" then
        Bug_Fields.Field("BG_USER_TEMPLATE_04").Value = Template_GetFullName(Bug_Fields.Field("BG_RESPONSIBLE").Value)
    End if

Works for me

ALM/Quality Center use User Name as the unique name for all users.

The Full Name is visibile when assigning users to any user field or as tooltip one hover