Welcome Serena Central users! CLICK HERE
The migration of the Serena Central community is currently underway. Be sure to read THIS MESSAGE to get your new login set up to access your account.
Anonymous_User Absent Member.
Absent Member.
2980 views

Login Script Error LOGIN 4.22.00-740 This Utility could not executeexternal program. The.

This error is occuing on mapped a search drive on a Windows 2000 machine. It occurs on the MAP S16:=NW-FS3\SYS:PUBLIC entry. The client is 4.83.6.6 SP1. We run this same line in tons of other contianer scripts with no problem. Can anyone help?

The login script is:

*****************************************************************************
NO_DEFAULT

*****************************************************************************
* Map Search Drives *
*****************************************************************************

MAP S16:=NW-FS3\SYS:PUBLIC

*****************************************************************************
* Map Application Drives *
*****************************************************************************

IF MEMBER OF ".MEDICAID CRITERIA.GROUPS.ADM.CMC" OR MEMBER OF ".HBOCREPORT.GROUPS.ADM.CMC" THEN
MAP ROOT M:=NW-FS1\VOL1:APPS
END

IF MEMBER OF ".NUTRITIONIST PRO.GROUPS.OP.CMC" OR MEMBER OF ".NUTIV.GROUPS.IP.CMC" OR MEMBER OF ".GERD CHECK.GROUPS.OP.CMC" THEN
MAP ROOT P:=NW-FS4\VOL1:APPS
END

#The following mapping was added for Dorothy Hollenkamp in SCLIN
IF MEMBER OF ".GENETICS PATIENT LETTERS.LAB.IP.CMC" OR MEMBER OF ".CYRILLIC..GROUPS.IP.CMC" OR MEMBER OF ".PEDIGREE PUBLISHER.GROUPS.IP.CMC" THEN
MAP ROOT O:=NW-FS4\VOL1:APPS
END

IF MEMBER OF ".CAREFILE.GROUPS.CMC" THEN
MAP ROOT R:=NW-FS1\VOL1:APPS
END

*****************************************************************************
* Map Data Drives *
*****************************************************************************
IF MEMBER OF "NEPH" THEN
MAP ROOT G:=NW-FS5\VOL1:DATA\DEPT\NEPH
END

IF MEMBER OF "SYNAGIS" THEN
MAP ROOT G:=NW-FS3\VOL1:DATA\DEPT\SYNAGIS
END

IF MEMBER OF "HEMA" THEN
MAP ROOT G:=NW-FS5\VOL1:DATA\DEPT\HEMA
END

IF MEMBER OF "CDEV" THEN
MAP ROOT G:=NW-FS5\VOL1:DATA\DEPT\CDEV
END

IF MEMBER OF "ENDO" THEN
MAP ROOT G:=NW-FS5\VOL1:DATA\DEPT\ENDO
END

IF MEMBER OF "QRM" THEN
MAP ROOT G:=NW-FS8\VOL1:DATA\DEPT\QRM
END

IF MEMBER OF "GI" THEN
MAP ROOT G:=NW-FS3\VOL1:DATA\DEPT\PULMGI
END

IF MEMBER OF "ED" THEN
MAP ROOT G:=NW-FS2\VOL1:DATA\DEPT\ED
END

IF MEMBER OF ".COMMITTEE.GROUPS.CMC" THEN
MAP ROOT K:=NW-FS5\VOL1:DATA\DEPT\MANAGE
END

IF MEMBER OF ".NEPH TRANSCRIPTION.NEPH.OP.CMC" THEN
MAP ROOT I:=NW-FS1\VOL1:DATA\DEPT\TRANSCRIPTION
END

IF MEMBER OF "SHARED" THEN
MAP ROOT J:=NW-FS3\VOL1:DATA\DEPT\SCLIN
END

MAP ROOT H:=NW-FS3\VOL1:DATA\USERS\SCLIN\%CN

*****************************************************************************
* Netware Application Launcher *
*****************************************************************************
IF OS = "WINNT" THEN
@Z:\NAL.EXE /NORM
@Z:\DWNTRUST.EXE
@Z:\CLNTRUST.EXE
END

IF OS="WIN98" THEN
@Z:\PUBLIC\NAL.EXE /NORM
@Z:\PUBLIC\DWNTRUST.EXE
@Z:\PUBLIC\CLNTRUST.EXE
END

IF OS = "WIN2K" THEN
@Z:\NAL.EXE /NORM
@Z:\DWNTRUST.EXE
@Z:\CLNTRUST.EXE
@Z:\ZAMClient\setup.exe -s -SMS
END

Tom McGhee
Senior Network Analyst
Children's Medical Center
One Childrens Plaza
Dayton, OH 45404
Phone:937-641-3210

Labels (1)
0 Likes
6 Replies
Anonymous_User Absent Member.
Absent Member.

Re: Login Script Error LOGIN 4.22.00-740 This Utility could not executeexternal program. The.

Tom,


> This error is occuing on mapped a search drive on a Windows 2000
> machine. It occurs on the MAP S16:=NW-FS3\SYS:PUBLIC entry. The client
> is 4.83.6.6 SP1. We run this same line in tons of other contianer
> scripts with no problem. Can anyone help?


Actually,

> #The following mapping was added for Dorothy Hollenkamp in SCLIN


The error is occuring here - you're trying to execute (#) the command
"The" with the parameters " following mapping was added ......."


--
Hamish Speirs
Novell Support Forums Volunteer Sysop.

http://haitch.net

(Please, no email unless requested. Unsolicited support emails will
probably be ignored)
0 Likes
Anonymous_User Absent Member.
Absent Member.

Re: Login Script Error LOGIN 4.22.00-740 This Utility could notexecute external program. The.

I'm sorry I don't follow your suggestion.....

Tom McGhee
Senior Network Analyst
Children's Medical Center
One Childrens Plaza
Dayton, OH 45404
Phone:937-641-3210

0 Likes
Anonymous_User Absent Member.
Absent Member.

Re: Login Script Error LOGIN 4.22.00-740 This Utility could notexecute external program. The.

Tom,

# and @ are the symbols to run/execute the following line in a NetWare login
script.
; or REM are used for comments.

--
Tony Pedretti
TransUnion Corporation


0 Likes
Anonymous_User Absent Member.
Absent Member.

Re: Login Script Error LOGIN 4.22.00-740 This Utility could not executeexternal program. The.

Tom,

> I'm sorry I don't follow your suggestion.....


In your login script your have the line "#The following mapping was
added for Dorothy Hollenkamp in SCLIN "

The # character thats been used as a comment indicator is actually a
command for login scripts. The # Character means execute the following
program - in this case its trying to execute an application called "The"
- change the # to REM


--
Hamish Speirs
Novell Support Forums Volunteer Sysop.

http://haitch.net

(Please, no email unless requested. Unsolicited support emails will
probably be ignored)
0 Likes
Anonymous_User Absent Member.
Absent Member.

Re: Login Script Error LOGIN 4.22.00-740 This Utility could notexecute external program. The.

Thank you very much, I completely overlooked that one. I guess I was looking to hard for other problems! I can't thank you enough!

Tom McGhee
Senior Network Analyst
Children's Medical Center
One Childrens Plaza
Dayton, OH 45404
Phone:937-641-3210

0 Likes
Anonymous_User Absent Member.
Absent Member.

Re: Login Script Error LOGIN 4.22.00-740 This Utility could not executeexternal program. The.

Tom,

> Thank you very much, I completely overlooked that one. I guess I was
> looking to hard for other problems! I can't thank you enough!


No problem - sometimes a second set of eyes is all it takes.


--
Hamish Speirs
Novell Support Forums Volunteer Sysop.

http://haitch.net

(Please, no email unless requested. Unsolicited support emails will
probably be ignored)
0 Likes
The opinions expressed above are the personal opinions of the authors, not of Micro Focus. By using this site, you accept the Terms of Use and Rules of Participation. Certain versions of content ("Material") accessible here may contain branding from Hewlett-Packard Company (now HP Inc.) and Hewlett Packard Enterprise Company. As of September 1, 2017, the Material is now offered by Micro Focus, a separately owned and operated company. Any reference to the HP and Hewlett Packard Enterprise/HPE marks is historical in nature, and the HP and Hewlett Packard Enterprise/HPE marks are the property of their respective owners.